Flash AS3.0構(gòu)建聲音可視化程序(波形圖)教程

發(fā)布時(shí)間：2014-11-30 14:52:37 作者：佚名

這篇教程是向腳本之家的朋友介紹Flash AS3.0構(gòu)建聲音可視化程序(波形圖)方法，教程很實(shí)用，主要向大家講解AS代碼的運(yùn)用。推薦到腳本之家，喜歡的朋友可以過(guò)學(xué)習(xí)一下

本例為Flash AS3.0實(shí)例教程，在教程中我們將學(xué)習(xí)運(yùn)用SoundMixer.computeSpectrum() 方法來(lái)構(gòu)建簡(jiǎn)單的聲音可視化程序（即波形圖），希望能給朋友們帶來(lái)幫助~~

AS3.0構(gòu)建簡(jiǎn)單的聲音可視化程序(波型圖)

Flash AS3.0實(shí)例:聲音可視化波形圖

使用 SoundMixer.computeSpectrum() 方法來(lái)顯示聲音波形圖

復(fù)制代碼

代碼如下:

import flash.display.Graphics;
import flash.events.Event;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundMixer;
import flash.net.URLRequest;
const PLOT_HEIGHT:int = 200;
const CHANNEL_LENGTH:int = 256;
var snd:Sound = new Sound();
var req:URLRequest = new URLRequest("月亮之上.mp3");　//配置聲音源文件地址(此為本地，可配置遠(yuǎn)程)
snd.load(req);
var channel:SoundChannel;
channel = snd.play();
addEventListener(Event.ENTER_FRAME, onEnterFrame);
snd.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
var bytes:ByteArray = new ByteArray();
function onEnterFrame(event:Event):void
{
SoundMixer.computeSpectrum(bytes, false, 0);

var g:Graphics = this.graphics;

g.clear();
g.lineStyle(0, 0x6600CC);
g.beginFill(0x6600CC);
g.moveTo(0, PLOT_HEIGHT);

var n:Number = 0;

// left channel
for (var i:int = 0; i < CHANNEL_LENGTH; i++)
{
n = (bytes.readFloat() * PLOT_HEIGHT);
g.lineTo(i * 2, PLOT_HEIGHT - n);
}
g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
g.endFill();

// right channel
g.lineStyle(0, 0xCC0066);
g.beginFill(0xCC0066, 0.5);
g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);

for (i = CHANNEL_LENGTH; i > 0; i--)
{
n = (bytes.readFloat() * PLOT_HEIGHT);
g.lineTo(i * 2, PLOT_HEIGHT - n);
}
g.lineTo(0, PLOT_HEIGHT);
g.endFill();
}
function onPlaybackComplete(event:Event)
{
removeEventListener(Event.ENTER_FRAME, onEnterFrame);
}

先加載并播放一個(gè)聲音文件，然后在播放聲音的同時(shí)偵聽(tīng)將觸發(fā) onEnterFrame() 方法的 Event.ENTER_FRAME 事件。onEnterFrame() 方法先調(diào)用 SoundMixer.computeSpectrum() 方法，后者將聲音波形數(shù)據(jù)存儲(chǔ)在 bytes ByteArray 對(duì)象中。

聲音波形是使用矢量繪圖 API 繪制的。 for 循環(huán)將循環(huán)訪(fǎng)問(wèn)第一批 256 個(gè)數(shù)據(jù)值（表示左立體聲聲道），然后使用 Graphics.lineTo() 方法繪制一條從每個(gè)點(diǎn)到下一個(gè)點(diǎn)的直線(xiàn)。第二個(gè) for 循環(huán)將循環(huán)訪(fǎng)問(wèn)下一批 256 個(gè)值，此時(shí)按相反的順序（從右到左）對(duì)它們進(jìn)行繪制。生成的波形圖可能會(huì)產(chǎn)生有趣的鏡像圖像效果。

以上就是Flash AS3.0構(gòu)建聲音可視化程序(波形圖)教程，希望大家喜歡！