問(wèn)：
您好，腳本專(zhuān)家！我有一個(gè)包含計(jì)算機(jī)名稱(chēng)列表的文本文件。如何按照字母順序?qū)υ撐募M(jìn)行排序？
-- LR
答：
您好，LR。如果想偷懶的話(huà)，我們就會(huì)告訴您：“對(duì)不起，您不能這樣做。”我們也可以就此脫身，因?yàn)?nbsp;Microsoft 的腳本編寫(xiě)技術(shù)中沒(méi)有一個(gè)方法能在打開(kāi)文本文件后對(duì)文件進(jìn)行排序。不過(guò)，嗨，“腳本專(zhuān)家”什么時(shí)候偷過(guò)懶呢？
噢，對(duì)了，我們是偷過(guò)幾次懶，不過(guò)希望所有的人都已經(jīng)忘了。不過(guò)，這次我們將向您提供一個(gè)解決辦法。
雖然沒(méi)有能直接對(duì)文本文件進(jìn)行排序的方法，但我們可以通過(guò)執(zhí)行以下操作最終達(dá)到相同的效果：1) 使用 FileSystemObject 將文件讀取到內(nèi)存中；2) 在內(nèi)存中按照字母順序?qū)ξ募M(jìn)行排序；3) 使用內(nèi)存中的已排序的數(shù)據(jù)替換文件現(xiàn)有的內(nèi)容。這些操作雖然有點(diǎn)兒繞彎兒，但是您最后將得到一個(gè)已按照字母順序進(jìn)行排序的文本文件，而這正是您想要的結(jié)果。
為了完成此任務(wù)，我們選擇使用一個(gè)斷開(kāi)連接的記錄集。還有其他的方法能夠?qū)崿F(xiàn)此目的（比如說(shuō)，冒泡排序），但是斷開(kāi)連接的記錄集能提供更多的靈活性，且更易于講解，尤其適合于那些曾有過(guò)數(shù)據(jù)庫(kù)編程經(jīng)驗(yàn)的用戶(hù)。我們?cè)诖藢⑾蚰?jiǎn)要介紹斷開(kāi)連接的記錄集；若要獲得有關(guān)其工作原理的詳細(xì)說(shuō)明，您可能需要訪(fǎng)問(wèn) Scripting Week 2 網(wǎng)絡(luò)廣播 Things the Scripting Guys Never Told You（腳本專(zhuān)家從未告訴過(guò)您的事情）。（作為額外提供的補(bǔ)充信息，該網(wǎng)絡(luò)廣播還將向您說(shuō)明如何使用冒泡排序?qū)蝹€(gè)文件數(shù)據(jù)進(jìn)行排序。）
在開(kāi)始之前，我們假定您有一個(gè)與以下內(nèi)容類(lèi)似的文本文件，文件的每一行都有一個(gè)計(jì)算機(jī)名稱(chēng)：
red-ws-02
atl-ws-01
sf-ws-02
atl-ws-02
atl-ws-03
red-ws-02
sf-ws-01

如何讀取這些計(jì)算機(jī)名稱(chēng)、對(duì)它們進(jìn)行排序并接著將排序后的列表寫(xiě)回該文本文件呢？我們可以使用一個(gè)與以下內(nèi)容類(lèi)似的腳本：
Const adVarChar = 200
Const MaxCharacters = 255
Const ForReading = 1
Const ForWriting = 2

Set DataList = CreateObject("ADOR.Recordset")
DataList.Fields.Append "ComputerName", adVarChar, MaxCharacters
DataList.Open

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\Scripts\Computers.txt", ForReading)

Do Until objFile.AtEndOfStream
    strLine = objFile.ReadLine
    DataList.AddNew
    DataList("ComputerName") = strLine
    DataList.Update
Loop

objFile.Close

DataList.Sort = "ComputerName"

DataList.MoveFirst
Do Until DataList.EOF
    strText = strText & DataList.Fields.Item("ComputerName") & vbCrLf
    DataList.MoveNext
Loop

Set objFile = objFSO.OpenTextFile("C:\Scripts\Computers.txt", ForWriting)

objFile.WriteLine strText
objFile.Close

首先，我們定義要?jiǎng)?chuàng)建斷開(kāi)連接的記錄集所需要的一系列常量。（應(yīng)將斷開(kāi)連接的記錄集視為一個(gè)只存在于內(nèi)存中的、與儲(chǔ)存在磁盤(pán)驅(qū)動(dòng)器上的物理數(shù)據(jù)庫(kù)無(wú)關(guān)的數(shù)據(jù)庫(kù)。）然后，我們使用以下這組代碼來(lái)創(chuàng)建一個(gè)由單個(gè)字段“ComputerName”組成的斷開(kāi)連接的記錄集：
Set DataList = CreateObject("ADOR.Recordset")
DataList.Fields.Append "ComputerName", adVarChar, MaxCharacters
DataList.Open

接下來(lái)，我們使用 FileSystemObject 來(lái)打開(kāi)文本文件 C:\Scripts\Computers.txt。此時(shí)，我們準(zhǔn)備開(kāi)始對(duì)所創(chuàng)建的記錄集進(jìn)行填充。我們要執(zhí)行的操作就是逐行讀取該文本文件。每讀取一行，我們都將使用“AddNew”方法向記錄集添加一條新記錄。我們將 ComputerName 字段的值設(shè)置為我們剛才在該文本文件中讀取的行（請(qǐng)記住，該文本文件的各行分別表示一個(gè)計(jì)算機(jī)名稱(chēng)），然后使用“Update”方法將記錄保存到該記錄集。繼續(xù)執(zhí)行此操作，直至我們讀取完該文本文件的每一行為止，然后我們將關(guān)閉該文件。 
是的，這聽(tīng)起來(lái)好像工作量很大，但是正如您看到的，所有的操作只需以下幾行代碼：
Do Until objFile.AtEndOfStream
    strLine = objFile.ReadLine
    DataList.AddNew
    DataList("ComputerName") = strLine
    DataList.Update
Loop

objFile.Close

接下來(lái)，我們需要對(duì)記錄集進(jìn)行排序。這是使用斷開(kāi)連接的記錄集而不使用冒泡排序或其他手動(dòng)排序算法的主要好處之一。對(duì)記錄集進(jìn)行排序只需執(zhí)行一行代碼：
DataList.Sort = "ComputerName"

現(xiàn)在我們就有了一個(gè)已排序的記錄集，需要使用該記錄集將數(shù)據(jù)寫(xiě)回文本文件。實(shí)現(xiàn)此目的最簡(jiǎn)單的方法就是遍歷此記錄集、抓取每條記錄并將整個(gè)記錄集保存在一個(gè)變量中。這就是下面所執(zhí)行的操作：
DataList.MoveFirst
Do Until DataList.EOF
    strText = strText & DataList.Fields.Item("ComputerName") & vbCrLf
    DataList.MoveNext
Loop

我們只是看一看各行記錄，然后將 ComputerName 字段的值存儲(chǔ)在變量 strText 中。請(qǐng)注意我們是如何執(zhí)行此操作的：我們將 strText 的值設(shè)置為 strText 中的任何值加上當(dāng)前 ComputerName 字段的值，再加上一個(gè)回車(chē)換行符（這正是 vbCrLf 常量所表示的）。我們將使用內(nèi)存中的一個(gè)名為 strText 的變量來(lái)結(jié)束此操作，該變量包含以下數(shù)據(jù)：
atl-ws-01
atl-ws-02
atl-ws-03
red-ws-02
red-ws-02
sf-ws-01
sf-ws-02

最后，重新打開(kāi)該文本文件（這次是為了寫(xiě)入）并使用“WriteLine”方法將現(xiàn)有的內(nèi)容替換為 strText 的值。因?yàn)?nbsp;strText 的值就是已排序的計(jì)算機(jī)名稱(chēng)列表，所以我們就完成了對(duì) C:\Scripts\Computers.txt 的內(nèi)容按照字母順序進(jìn)行的排序。

最新評(píng)論