VB6中的LSet語(yǔ)句和RSet語(yǔ)句詳解

更新時(shí)間：2014年07月29日 11:13:57 投稿：junjie

這篇文章主要介紹了VB6中的LSet語(yǔ)句和RSet語(yǔ)句詳解,LSet語(yǔ)句和RSet語(yǔ)句不太常用,所以知道的人不多,需要的朋友可以參考下

VB6中有幾種長(zhǎng)得很像的語(yǔ)句：Let、Set、LSet、RSet。

Let用于一般變量的賦值：

復(fù)制代碼代碼如下:

[Let] varname = expression

大部分情況下我們都省略Let，直接用等號(hào)賦值，以致于不少人根本不知道Let的存在。

Set用于對(duì)象的賦值，將變量指向?qū)ο蟛⒃黾訉?duì)象的引用計(jì)數(shù)，也有不少人不知道引用計(jì)數(shù)為何物。

那么LSet是干什么用的呢？咋一看好像是Let和Set的結(jié)合體，其實(shí)不然。LSet中的L是Left的縮寫，與之對(duì)應(yīng)的是RLet。你問(wèn)我怎么知道L是Left的縮寫？文檔上面寫的唄：

復(fù)制代碼代碼如下:

LSet Statement

Left aligns a string within a string variable, or copies a variable of one user-defined type to another variable of a different user-defined type.

RSet Statement

Right aligns a string within a string variable.

LSet比RSet多出一個(gè)功能，先不看這個(gè)，先看相同的部分，兩者分別用來(lái)在一字符串變量中將一字符串往左對(duì)齊（右對(duì)齊）。什么意思呢？其實(shí)光看文檔我也沒(méi)不懂，實(shí)際測(cè)試一下好了：

復(fù)制代碼代碼如下:

Sub Main()

    Dim url As String

    Dim s As String

    Let url = "http://chabaoo.cn"

    s = String$(20, "*")

    LSet s = url

    Debug.Print s

    RSet s = url

    Debug.Print s

End Sub

輸出（注意空格）：

復(fù)制代碼代碼如下:

http://chabaoo.cn

的確是左對(duì)齊的右對(duì)齊，而且還多此一舉的把我們的星號(hào)*替換成了空格，這有什么用呢？以我看來(lái)，似乎也許大概真的沒(méi)什么用，不知道設(shè)計(jì)者是怎么想的。

不過(guò)LSet的另一個(gè)功能卻是很強(qiáng)大的，可以將一用戶定義類型變量復(fù)制到另一用戶自定義類型變量。這又是什么意思？

還是舉個(gè)例子來(lái)說(shuō)明，IP地址知道吧？我這里ping百度返回的IP是61.135.169.125，這種格式的IP地址只是用來(lái)給人類看的，IP在計(jì)算機(jī)內(nèi)部其實(shí)是用32位整數(shù)來(lái)表示。如何用VB將xxx.xxx.xxx.xxx格式的IP地址轉(zhuǎn)成32位整數(shù)形式？一番Google之后，可以寫出類似于這樣的代碼：

復(fù)制代碼代碼如下:

Sub Main()
Debug.Print IPToLong("61.135.169.125")
End Sub

Private Function IPToLong(IPStr As String) As Long
   Dim Str() As String, HEXStr As String, TempStr As String
   Dim x As Long

   Str = Split(IPStr, ".")
   HEXStr = ""
   For x = 0 To UBound(Str)
      TempStr = Hex(Str(x))
      HEXStr = HEXStr & String(2 - Len(TempStr), "0") & TempStr
   Next x
   IPToLong = CLng("&H" & HEXStr)
End Function

代碼可以正常工作，這沒(méi)什么問(wèn)題，不過(guò)我們可以用LSet語(yǔ)句寫出更“高級(jí)”的代碼：

復(fù)制代碼代碼如下:

Private Type myBytes
    B1 As Byte
    B2 As Byte
    B3 As Byte
    B4 As Byte
End Type

Private Type myLong
Val As Long
End Type

'By Demon
'http://jb51.net

Public Function IP2Long(ip As String) As Long
    Dim a() As String
    Dim b As myBytes
    Dim l As myLong

    a = Split(ip, ".")
    '注意Little-Endian
    b.B1 = CByte(a(3))
    b.B2 = CByte(a(2))
    b.B3 = CByte(a(1))
    b.B4 = CByte(a(0))
    LSet l = b
    IP2Long = l.Val
End Function

用LSet將myBytes類型的變量復(fù)制到myLong類型的變量，很好很強(qiáng)大?？匆幌律傻膮R編代碼：

復(fù)制代碼代碼如下:

00401A0E   lea     eax, dword ptr [ebp-0x20]   ; 變量b的地址

00401A11   push    eax

00401A12   lea     eax, dword ptr [ebp-0x14]   ; 變量l的地址

00401A15   push    eax

00401A16   push    0x4

00401A18   call    __vbaCopyBytes              ;  jmp to MSVBVM60.__vbaCopyBytes

調(diào)用的是MSVBVM60.DLL中的__vbaCopyBytes，第一個(gè)參數(shù)是需要復(fù)制的字節(jié)，第二個(gè)參數(shù)是目標(biāo)地址，第三個(gè)參數(shù)是源地址，與C標(biāo)準(zhǔn)庫(kù)中的memcpy函數(shù)類似，只不過(guò)參數(shù)的順序不一樣，其內(nèi)部實(shí)現(xiàn)無(wú)非就是匯編中的串傳送指令：

復(fù)制代碼代碼如下:

72A1A0F3 >  mov     ecx, dword ptr [esp+0x4]

72A1A0F7    push    esi

72A1A0F8    mov     esi, dword ptr [esp+0x10]

72A1A0FC    push    edi

72A1A0FD    mov     edi, dword ptr [esp+0x10]

72A1A101    mov     eax, ecx

72A1A103    mov     edx, edi

72A1A105    shr     ecx, 0x2

72A1A108    rep     movs dword ptr es:[edi], dword ptr [esi]

72A1A10A    mov     ecx, eax

72A1A10C    mov     eax, edx

72A1A10E    and     ecx, 0x3

72A1A111    rep     movs byte ptr es:[edi], byte ptr [esi]

72A1A113    pop     edi

72A1A114    pop     esi

72A1A115    retn    0xC

需要注意的是文檔中警告我們：

復(fù)制代碼代碼如下:

Warning Using LSet to copy a variable of one user-defined type into a variable of a different user-defined type is not recommended. Copying data of one data type into space reserved for a different data type can cause unpredictable results.

When you copy a variable from one user-defined type to another, the binary data from one variable is copied into the memory space of the other, without regard for the data types specified for the elements.

用LSet復(fù)制用戶定義類型變量是不提倡的，這可能導(dǎo)致預(yù)料之外的結(jié)果（例如結(jié)構(gòu)沒(méi)有對(duì)齊），所以，除非你知道自己在做什么，否則不要使用LSet語(yǔ)句。

您可能感興趣的文章: