use master
go
if object_id('sp_RefreshIndex') Is not null
    Drop Proc sp_RefreshIndex
Go
create proc sp_RefreshIndex
(
    @Reorganize_Fragmentation_Percent    smallint = 5    -- 當(dāng)邏輯碎片百分比 > 5%  重新組織索引
    ,@Rebuild_Fragmentation_Percent        smallint = 30    -- 當(dāng)邏輯碎片百分比 > 30% 重新生成索引
)
as
begin
    /* 調(diào)用方法：
.針對當(dāng)前實例所有數(shù)據(jù)庫：    exec sys.sp_MSforeachdb 'use ?;exec sp_RefreshIndex'
.針對當(dāng)前數(shù)據(jù)庫：            exec sp_RefreshIndex
    */

    --對系統(tǒng)數(shù)據(jù)庫不作重新組織索引和重新生成索引
    if (db_name() in ('master','model','msdb','tempdb')) return;   

    --如果邏輯碎片（索引中的無序頁）的百分比 <= 5% ，就不作重新組織索引和重新生成索引
    if not exists(select 1 from sys.dm_db_index_physical_stats(db_id(),null,null,null,null) a where a.index_id>0 and a.avg_fragmentation_in_percent > @Reorganize_Fragmentation_Percent) return

   
    print replicate('-',60)+char(13)+char(10)+replicate(' ',14)+N'對數(shù)據(jù)庫 '+quotename(db_name())+N' 進(jìn)行索引優(yōu)化'+replicate(' ',20)+char(13)+char(10)   

    declare @sql nvarchar(2000),@str nvarchar(2000)

    declare cur_x cursor for
        select 'alter index '+quotename(a.name)+' on '+quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+case when b.avg_fragmentation_in_percent<=@Rebuild_Fragmentation_Percent then ' reorganize;'else ' rebuild;'end as [sql]
                ,case when b.avg_fragmentation_in_percent<=@Rebuild_Fragmentation_Percent then N'重新組織索引：' else N'重新生成索引：'end +quotename(object_schema_name(a.object_id))+'.'+quotename(object_name(a.object_id))+'.'+quotename(a.name) as [str]
            from sys.indexes a
                inner join sys.dm_db_index_physical_stats(db_id(),null,null,null,null) b on b.object_id=a.object_id
                    and b.index_id=a.index_id   
            where a.index_id>0   
                and b.avg_fragmentation_in_percent > @Reorganize_Fragmentation_Percent
            order by object_name(a.object_id),a.index_id

    open cur_x
    fetch next from cur_x into @sql,@str   

    while (@@fetch_status = 0)
    begin

        exec(@sql)
        print @str
        fetch next from cur_x into @sql,@str   

    end
    close cur_x
    deallocate cur_x

end
go
exec sp_ms_marksystemobject 'sp_RefreshIndex'
go

use master
go
exec sys.sp_MSforeachdb 'use ?;exec sp_RefreshIndex'
go