批處理中的預處理實現(xiàn)代碼

更新時間：2011年01月11日 01:07:48 作者：

如果你對脫字字符“^”的處理機制比較熟悉那么可以接著閱讀，否則請先參考脫字字符的相關文章。

轉載自 nxhujiee最終編輯 LJ_SunTB批處理中的【預處理】
━━━━━━━━━━━━━━━━━━━━━━━━━━

如果你對脫字字符“^”的處理機制比較熟悉那么可以接著閱讀，否
則請先參考脫字字符的相關文章。

一、預處理究竟要做什么？

根據(jù)我的經驗，預處理要做的是變量值的替換和特殊符號的處理。究竟先執(zhí)行哪個操作呢，我認為要先進行變量值的替換。理由有三：

1、從邏輯上看

set var=2&echo %var%
類似于這樣的語句，如果說先進行特殊符號處理的話，勢必要先處理符號“&”，而“&”是用來連接兩條命令的，這樣一來該行就理所應當?shù)谋焕斫鉃閮删洌敲次覀冞€要變量延遲干嘛。這里應該是
先對變量var賦值，然后處理特殊符號“&”。

2、從運行結果看

復制代碼代碼如下:

 
@echo off 
set var=^^^> 
echo %var% 
pause 

這句“set var=^^^>”首先也會被預處理，預處理之后var的值為“^>”。
本例的輸出結果是“>”，因此可以證明系統(tǒng)先將變量的值替換為“^>”然后再處理特殊符號“^”。

3、從變量替換上看

復制代碼代碼如下:

 
@echo off 
set ^&var=hero 
echo %&var% 
pause 

結果：顯示“hero”
這也說明變量的替換先于特殊符號的處理。

二、啟動了變量延遲之后預處理又是如何進行呢？

我的看法是這樣的：如果語句中存在英文嘆號“!”則會被預處理兩次，其它情況仍然是預處理一次。由于脫字字符比較特殊，因此在此借助該符號寫幾個例子說明一下。

（一）

復制代碼代碼如下:

 
@echo off 
echo !^^^^^> 
setlocal enabledelayedexpansion 
echo !^^^^^> 
pause 

兩個echo語句的結果不同。下面做一下分析：
對于第一個echo語句，變量延遲沒有開啟，進行預處理的時候該句就被預處理為“echo !^^>”，這也就是輸出的結果。由此可見預處理只進行了一次。

對于第二個echo語句，此時變量延遲開啟，由于有“!”存在，首先進行一次預處理得到“echo !^^>”，再進行一次得到“echo ^>”，結果也是如此。
之所以沒有輸出嘆號，是因為開啟了變量延遲，嘆號就變?yōu)榱颂厥夥枴?

（二）

復制代碼代碼如下:

 
@echo off 
setlocal enabledelayedexpansion 
set var=hero 
echo !var! 
pause 

像這里的“echo !var!”不是沒有被預處理，而是被預處理了兩次?？聪旅娴倪@段代碼就可以理解了。

復制代碼代碼如下:

 
@echo off 
setlocal enabledelayedexpansion 
set var=hero 
echo !var!^^^^^> 
pause 

運行的結果為：“hero^>”。我們來分析一下，進行第一次預處理時，由于“!var!”，因此先不替換變量值而進行特殊符號的處理，處理完后就成了“echo !var!^^>”；之后再進行一次預處理，
此時就要替換“!var!”了，處理完后就成了“echo hero^>”。

（三）
我們再來看看當變量延遲開啟時語句中不存在英文嘆號的情況。

復制代碼代碼如下:

 
@echo off 
echo ^^^^^> 
setlocal enabledelayedexpansion 
echo ^^^^^> 
pause 

@echo off 
set var=hero 
echo %var%^^^^^> 
setlocal enabledelayedexpansion 
echo %var%^^^^^> 
pause 

怎么樣，也就是說如果沒有“!”就不會進行第二次處理。

（四）
對于!!型，特殊符號的處理是在變量替換之前進行的。

例、

復制代碼代碼如下:

 
@echo off 
setlocal enabledelayedexpansion 
set ^&var=hero 
echo !&var! 
pause 

這段代碼運行結果是錯誤的。

例、

復制代碼代碼如下:

 
@echo off 
setlocal enabledelayedexpansion 
set var=^& 
echo !var! 
pause 

這段代碼運行結果是正確的。

（五）
既然都要處理符號，那么%%型和!!型的符號處理會不會是同一個過程？

（一）中的例子已經可以說明問題，不過我還有例子可以證明。

例、

復制代碼代碼如下:

 
@echo off 
echo "^^^^^^^^"!! 
setlocal enabledelayedexpansion 
echo "^^^^^^^^"!! 
pause 

對于%%型，在符號處理時，不處理雙引號間的脫字字符；而對于!!型則相反。

三、call引出的一些問題

（一）
call與脫字字符

例、

復制代碼代碼如下:

 
@echo off 
set /p var=<hero.txt 
echo "%var%" 
call echo "%var%" 
pause 

其中hero.txt中的內容為8個脫字字符：^^^^^^^^

結果是：
"^^^^^^^^"
"^^^^^^^^^^^^^^^^"
請按任意鍵繼續(xù). . .

結果是否有些出乎意料？我們知道，系統(tǒng)在預處理時不會處理雙引號間的脫字字符，那就意味著是call命令將其后的脫字字符數(shù)量加了倍?？磥韈all命令和脫字字符還真有點“曖昧”。

例、

復制代碼代碼如下:

 
@echo off 
set /p var=<hero.txt 
echo %var% 
call echo %var% 
pause 

本例中變量var的值為8個“^”，運行“call echo %var%”時，首先進行變量替換把%var%替換為^^^^^^^^，再經一次符號的處理變?yōu)閊^^^，此時由于call命令使得脫字字符數(shù)目增加一倍變?yōu)?個，然后再進行
call本身的預處理，這樣結果就為4個“^”。

這樣就能解釋下面的代碼為什么會顯示4個“^”。

復制代碼代碼如下:

 
@echo off 
call call call call echo ^^^^^^^^ 
pause 

（二）
call與其它特殊字符
這里所說的“其它特殊字符”主要指&、>、|等。

這里請允許我自定義兩個名詞：
主預處理過程：系統(tǒng)本身預處理過程的總稱，其中包括了%%型和!!型。
次預處理過程：由于call命令引起的預處理過程的總稱。
“其它特殊字符”是在主預處理過程中被系統(tǒng)識別的，而在次預處理
過程中對這些符號的識別是有問題的。

例、

復制代碼代碼如下:

 
@echo off 
call echo hero!^&pause 
pause 

本例中，經過主預處理過程，&被識別為普通字符，而在次預處理過程中符號&的識別將產生問題。正如《命令行參考》中提到的--不要在call 命令中使用管道和重定向符號。（這倒不是說call語句中不能使
用那些符號，而是這些符號不能作為參數(shù)傳遞給call命令。）

這也從某種程度上說明某行語句的句子結構（一條還是多條）和功能（是從定向輸出還是其它）是在主預處理過程中確定的。

以上所有內容，只是我個人的看法，由于沒有官方文檔的支持，因此僅供參考。

那么我們學了以上種種內容又有什么實際用途呢？我想，懂得了以上道理就可以寫出更加個性化的代碼，同時也可以作為一種偽裝術在實際中應用。

復制代碼代碼如下:

 
@echo off 
set ^&=setlocal enabledelayedexpansion 
set ^^^^^hero=^^^^^&p 
set ^au=^^^au 
set ^^^^^^^^^=障眼法 
%&% 
set ^^^^^se=^^^se! 
echo %^^^^%!%^^hero%!au%^se% 

怎么樣，這段代碼能看明白嗎？