快捷導(dǎo)航

Sql Server 數(shù)據(jù)庫(kù)索引整理語(yǔ)句,自動(dòng)整理數(shù)據(jù)庫(kù)索引

更新時(shí)間：2009年07月01日 01:06:49 作者：

我們就要定期的對(duì)數(shù)據(jù)庫(kù)的索引進(jìn)行維護(hù) 我在MSDN上發(fā)現(xiàn)了這個(gè)腳本不過其中有些小問題我已經(jīng)修正大家可以使用這個(gè)腳本對(duì)數(shù)據(jù)庫(kù)的索引進(jìn)行日常維護(hù)

在一個(gè)大型數(shù)據(jù)庫(kù)中，數(shù)據(jù)的更改是非常頻繁的。
而建立在這些數(shù)據(jù)上的索引也是需要經(jīng)常去維護(hù)的。
否則這這些數(shù)據(jù)索引就起不到起應(yīng)起的作用。甚至?xí)蔀閿?shù)據(jù)庫(kù)本身的負(fù)擔(dān)。
我們就要定期的對(duì)數(shù)據(jù)庫(kù)的索引進(jìn)行維護(hù) 我在MSDN上發(fā)現(xiàn)了這個(gè)腳本不過其中有些小問題我已經(jīng)修正大家可以使用這個(gè)腳本對(duì)數(shù)據(jù)庫(kù)的索引進(jìn)行日常維護(hù)

復(fù)制代碼代碼如下:

SET NOCOUNT ON; 
DECLARE @objectid int; 
DECLARE @indexid int; 
DECLARE @partitioncount bigint; 
DECLARE @schemaname sysname; 
DECLARE @objectname sysname; 
DECLARE @indexname sysname; 
DECLARE @partitionnum bigint; 
DECLARE @partitions bigint; 
DECLARE @frag float; 
DECLARE @command varchar(8000); 
DECLARE @dbId int; 
-- ensure the temporary table does not exist 
IF EXISTS (SELECT name FROM sys.objects WHERE name = 'work_to_do') 
DROP TABLE work_to_do; 
-- conditionally select from the function, converting object and index IDs to names. 
set @dbId=DB_ID(); 
SELECT 
object_id AS objectid, 
index_id AS indexid, 
partition_number AS partitionnum, 
avg_fragmentation_in_percent AS frag 
INTO work_to_do FROM sys.dm_db_index_physical_stats (@dbId, NULL, NULL , NULL, 'LIMITED') 
WHERE avg_fragmentation_in_percent > 10.0 AND index_id > 0; 
-- Declare the cursor for the list of partitions to be processed. 
DECLARE partitions CURSOR FOR SELECT * FROM work_to_do; 

-- Open the cursor. 
OPEN partitions; 

-- Loop through the partitions. 
FETCH NEXT 
FROM partitions 
INTO @objectid, @indexid, @partitionnum, @frag; 

WHILE @@FETCH_STATUS = 0 
BEGIN; 
SELECT @objectname = o.name, @schemaname = s.name 
FROM sys.objects AS o 
JOIN sys.schemas as s ON s.schema_id = o.schema_id 
WHERE o.object_id = @objectid; 

SELECT @indexname = name 
FROM sys.indexes 
WHERE object_id = @objectid AND index_id = @indexid; 

SELECT @partitioncount = count (*) 
FROM sys.partitions 
WHERE object_id = @objectid AND index_id = @indexid; 

-- 30 is an arbitrary decision point at which to switch between reorganizing and rebuilding 
IF @frag < 30.0 
BEGIN; 
SELECT @command = 'ALTER INDEX [' + @indexname + '] ON ' + @schemaname + '.[' + @objectname + '] REORGANIZE'; 
IF @partitioncount > 1 
SELECT @command = @command + ' PARTITION=' + CONVERT (CHAR, @partitionnum); 

EXEC (@command); 
END; 

IF @frag >= 30.0 
BEGIN; 
SELECT @command = 'ALTER INDEX [' + @indexname +'] ON ' + @schemaname + '.[' + @objectname + '] REBUILD'; 
IF @partitioncount > 1 
SELECT @command = @command + ' PARTITION=' + CONVERT (CHAR, @partitionnum); 

EXEC (@command); 
END; 
PRINT 'Executed ' + @command; 

FETCH NEXT FROM partitions INTO @objectid, @indexid, @partitionnum, @frag; 
END; 
-- Close and deallocate the cursor. 
CLOSE partitions; 
DEALLOCATE partitions; 

-- drop the temporary table 
IF EXISTS (SELECT name FROM sys.objects WHERE name = 'work_to_do') 
DROP TABLE work_to_do; 
GO 