Shader "Unlit/DepthOutline"
{
 Properties{
 _MainTex("MainTex",2D) = "white"{}
 _RimFactor("RimFactor",Range(0.0,5.0))=1.0
 _DistanceFactor("DistanceFactor",Range(0.0,10.0))=1.0
 _RimColor("RimColor",Color)=(1,0,0,1)
 _DistanceFactor2("DistanceFactor2",Range(0.0,10.0))=1.0
 _DistanceFactor3("DistanceFactor3",Range(0.0,5.0)) = 1.0
 }
 SubShader{
 Tags{"Queue" = "Transparent" "RenderType" = "Transparent" "IgnoreProjector"="true"}
 Pass{
 Blend SrcAlpha OneMinusSrcAlpha
 ZWrite Off
 Cull Off
 CGPROGRAM
 #include "UnityCG.cginc"
 #pragma vertex vert
 #pragma fragment frag

 sampler2D _MainTex;
 float4 _MainTex_ST;
 sampler2D _CameraDepthTexture;
 float _RimFactor;
 float _DistanceFactor;
 float4 _RimColor;
 float _DistanceFactor2;
 float _DistanceFactor3;
 
 struct a2v {
 float4 vertex:POSITION;
 float2 uv:TEXCOORD0;
 float3 normal:NORMAL;
 };
 
 struct v2f {
 float2 uv:TEXCOORD0;
 float4 pos:SV_POSITION;
 float4 screenPos:TEXCOORD1;
 float3 worldNormal:TEXCOORD2;
 float3 worldViewDir:TEXCOORD3;
 };

 v2f vert(a2v v) {
 v2f o;
 o.pos = UnityObjectToClipPos(v.vertex);
 //ComputeScreenPos函數，得到歸一化前的視口坐標xy
 //z分量為裁剪空間的z值，范圍[-Near,Far]
 o.screenPos = ComputeScreenPos(o.pos);
 o.uv = TRANSFORM_TEX(v.uv,_MainTex);
 //COMPUTE_EYEDEPTH函數，將z分量范圍[-Near,Far]轉換為[Near,Far]
 COMPUTE_EYEDEPTH(o.screenPos.z);
 o.worldNormal = UnityObjectToWorldNormal(v.normal);
 o.worldViewDir = WorldSpaceViewDir(v.vertex).xyz;
 return o;
 }

 float4 frag(v2f i):SV_Target {
 float3 mainTex = 1-tex2D(_MainTex,i.uv).xyz;
 //獲取深度紋理,通過LinearEyeDepth函數將采樣的深度紋理值轉換為對應的深度范圍[Near~Far]
 float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture,UNITY_PROJ_COORD(i.screenPos)));
 //觀察空間深度差,值越小顏色值越大
 float distance =1 - saturate(sceneZ - i.screenPos.z);
 //消除內部深度變化較大時產生的鋸齒
 if (distance>0.999999)
 {
 distance = 0;
 }
 //調整深度差值的變化曲線
 distance = pow(saturate(_DistanceFactor * log(distance) + _DistanceFactor3), _DistanceFactor2);

 //角度越大邊緣光越亮
 float rim =1 - abs(dot(normalize(i.worldNormal), normalize(i.worldViewDir)));
 rim = pow(rim, _RimFactor);
 float4 col = float4(0,0,0,0);
 col = lerp(col, float4(_RimColor.rgb,0.3), mainTex.r);
 //根據邊緣光以及深度差漸變
 col = float4(_RimColor.rgb,lerp(col.a,_RimColor.a, distance));
 col = lerp(col, _RimColor, rim);
 return col;
 }

 ENDCG
 }
 }
}