快速將珊瑚蟲IP數(shù)據(jù)庫轉MS SQL2005的圖文教程

更新時間：2008年08月02日 01:52:46 作者：

在幻想曲BLOG上看到不少朋友說，最近服務器上的IP數(shù)據(jù)好像不是很準確，于是重新做了一個新的，不少朋友可能需要這個數(shù)據(jù)庫，因為文件太大的緣故，所以直接提供快速轉換方法。

-- 建立IP轉換到十進制方法  
USE [BasName]  
GO  
/****** 對象:  UserDefinedFunction [dbo].[X16ToDe]    腳本日期: 09/19/2007 13:56:15 ******/  
SET ANSI_NULLS ON  
GO  
SET QUOTED_IDENTIFIER ON  
GO  

-- =============================================  
-- Author:        <Author,,Name>  
-- Create date: <Create Date, ,>  
-- Description:    轉換IP為十進制  
-- =============================================  
Create FUNCTION [dbo].[X16ToDe]  
(  
    @Old_IP nvarchar(15)  
)  
RETURNS numeric  
AS  
BEGIN  
    DECLARE  
        @CharIndex INT,  
        @CurrPoint INT,  
        @SingleValue NVARCHAR(5),  
        @Cache numeric  

    SET @CharIndex = 1  
    SET @CurrPoint = CHARINDEX('.',@Old_IP,@CharIndex)  
    SET @SingleValue = SUBSTRING(@Old_IP,@CharIndex,@CurrPoint - @CharIndex)  
    SET @Cache = cast(@SingleValue as numeric)*16777216  

    SET @CharIndex = @CurrPoint + 1  
    SET @CurrPoint = CHARINDEX('.',@Old_IP,@CharIndex)  
    SET @SingleValue = SUBSTRING(@Old_IP,@CharIndex,@CurrPoint - @CharIndex)  
    SET @Cache = @Cache + cast(@SingleValue as numeric)*65536  

    SET @CharIndex = @CurrPoint + 1  
    SET @CurrPoint = CHARINDEX('.',@Old_IP,@CharIndex)  
    SET @SingleValue = SUBSTRING(@Old_IP,@CharIndex,@CurrPoint - @CharIndex)  
    SET @Cache = @Cache + cast(@SingleValue as numeric)*256  

    SET @CharIndex = @CurrPoint + 1  
    SET @SingleValue = SUBSTRING(@Old_IP,@CharIndex,len(@Old_IP)- @CharIndex + 1)  
    SET @Cache = @Cache + cast(@SingleValue as numeric)  

    RETURN @Cache;  
END 

復制代碼代碼如下:

-- 建立十進制新表  
USE [BasName]  
GO  
/****** 對象:  Table [dbo].[IP_Real]    腳本日期: 09/19/2007 14:01:31 ******/  
SET ANSI_NULLS ON  
GO  
SET QUOTED_IDENTIFIER ON  
GO  
Create TABLE [dbo].[IP_Real](  
    [startip] [numeric](18, 0) NULL,  
    [endip] [numeric](18, 0) NULL,  
    [country] [nvarchar](50) NULL,  
    [local] [nvarchar](200) NULL  
) ON [PRIMARY] 

這一步你可以自己按照你的情況來做，我是為了加快數(shù)據(jù)庫索引的速度，所以將IP全部轉換為十進制，存到一個新表里面。

-- 格式化省份

復制代碼代碼如下:

Update [BasName].[dbo].[IP]  
   SET [country] = replace([country],N'省',N'省 ') 

-- 刪除CZ88.NET

復制代碼代碼如下:

Update [BasName].[dbo].[IP]  
   SET [country] = replace([country],N'CZ88.NET',N'') 

-- 將地區(qū)提出
Update [BasName].[dbo].[IP]
   SET [local] = SUBSTRING([country],CHARINDEX(' ',[country],1)+1,len([country]))

-- 存為國家或省份
Update [BasName].[dbo].[IP]
   SET [country] = SUBSTRING([country],0,CHARINDEX(' ',[country],1))

-- 去處前后導空格
Update [BasName].[dbo].[IP]
   SET [country] = Rtrim(Ltrim([country]))
      ,[local] = Rtrim(Ltrim([local]))

-- 轉換IP為十進制，并寫入新表
Insert INTO [BasName].[dbo].[IP_Real]
           ([startip]
           ,[endip]
           ,[country]
           ,[local])
Select dbo.X16ToDe([startip])
      ,dbo.X16ToDe([endip])
      ,[country]
      ,[local]
  FROM [BasName].[dbo].[IP]
order by [startip] ASC

最后測試一下看看：

程序代碼

-- 測試
DECLARE @IPNumber numeric
set @IPNumber = dbo.X16ToDe('219.140.31.91')

Select [startip]
      ,[endip]
      ,[country]
      ,[local]
  FROM [BasName].[dbo].[IP_Real]
Where [startip] <= @IPNumber and [endip] >= @IPNumber

基本所有的轉換最多3分鐘完成，比自己寫應用程序轉換要快的多。