在ASP應用程序中限制重復提交同一表單

更新時間：2006年10月09日 00:00:00 作者：

在Internet上我們每天都會遇到數(shù)不清的表單，也看到其中大部分并沒有限制用戶多次提交同一個表
單。缺乏這種限制有時候會產(chǎn)生某些預料不到的結果，如重復訂閱郵件服務或重復投票等?；蛟S一些
asp初學者并不清楚在asp應用中如何限制重復提交同一表單，所以在這里向大家介紹在ASP應用中防止
用戶在當前會話期間多次提交同一表單的一個簡單方法。

　　這個工作主要由四個子程序組成，在較為簡單的應用場合，你只要將這些代碼放在包含文件中直
接引用即可；對于那些較為復雜的環(huán)境，我們在文章的最后給出一些改進建議。

　　一、基本工作過程

　　下面我們依次討論這四個子程序。　

?。ㄒ唬┏跏蓟?

　　這里我們要在Session對象中保存兩個變量，其中：

　　 ⑴ 每一個表單對應一個稱為FID的唯一標識，為使該值唯一要用到一個計數(shù)器。

　　 ⑵ 每當一個表單成功提交，必須在一個Dictionary對象中存儲它的FID。

　　我們用一個專用的過程來初始化上述數(shù)據(jù)。雖然以后各個子程序都要調用它，但實際上每一個會
話期間它只執(zhí)行一次：

復制代碼代碼如下:

 
Sub InitializeFID() 
　If Not IsObject(Session("FIDList")) Then 
　　Set Session("FIDList")=Server.CreateObject("Scripting.Dictionary") 
　　Session("FID")=0 
　End If 
End Sub 

（二）生成表單的唯一標識符

　　下面這個函數(shù)GenerateFID()用于生成表單的唯一標志。該函數(shù)首先將FID值加1，然后返回它：

復制代碼代碼如下:

 
Function GenerateFID() 
　InitializeFID 
　Session("FID") = Session("FID") + 1 
　GenerateFID = Session("FID") 
End Function 

（三）登記已提交表單

　　當表單成功地提交時，在Dictionary對象中登記它的唯一標識：

復制代碼代碼如下:

 
Sub RegisterFID() 
　Dim strFID 
　InitializeFID 
　strFID = Request("FID") 
　Session("FIDlist").Add strFID, now() 
End Sub 

（四）檢查表單是否重復提交

　　在正式處理用戶提交的表單之前，應該在Dictionary對象中檢查它的FID是否已經(jīng)登記。下面的
CheckFID()函數(shù)用來完成這個工作，如已經(jīng)登記，它返回FALSE，否則返回TRUE:

復制代碼代碼如下:

 
Function CheckFID() 
　Dim strFID 
　InitializeFID 
　strFID = Request("FID") 
　CheckFID = not Session("FIDlist").Exists(strFID) 
End Function 

二、如何使用

　　有兩個地方要用到上述函數(shù)，即表單生成時與結果處理時。假設上述四個子程序已經(jīng)放入包含文
件Forms.inc中，下面的代碼根據(jù)FID值來決定生成表單還是處理表單結果，它所描述的處理過程適合
于大多數(shù)ASP應用：

復制代碼代碼如下:

 
< %Option Explicit%> 
< !--#include file="forms.inc"--> 
< HTML> 
< HEAD> 
< TITLE>表單提交測試< /TITLE> 
< /HEAD 
< BODY> 
< % 
If Request("FID") = "" Then 
GenerateForm 
Else 
ProcessForm 
End If 
%> 
< /BODY> 
< /HTML> 

GenerateForm負責生成表單，表單中應該含有一個隱藏的FID，如：

復制代碼代碼如下:

 
< % 
Sub GenerateForm() 
%> 
< form action="< %=Request.ServerVariables("PATH_INFO")%>" method=GET> 
< input type=hidden name=FID value="< %=GenerateFID()%>"> 
< input type=text name="param1" value=""> 
< input type=submit value="OK"> 
< /form> 
< % 
End Sub 
%> 

ProcessForm負責處理通過表單提交的內容，但在處理之前應該先調用CheckFID()檢查當前表單是否已
經(jīng)提交，代碼類如：

復制代碼代碼如下:

 

< % 
Sub ProcessForm() 
　If CheckFID() Then 
　　Response.Write "你輸入的內容是" & Request.QueryString("param1") 
　　RegisterFID 
　Else 
　　Response.Write "此表單只能提交一次!" 
　End If 
End Sub 
%>  

三、限制與改進措施

　　上面我們介紹了在當前會話期間限制同一表單被多次提交的一種方法。在實際應用中可能需要從
多方面加以改進，例如：　

　　 ⑴ 在登記表單ID之前檢查用戶輸入數(shù)據(jù)的合法性，使得數(shù)據(jù)不合法時用戶可以按“后退”按鈕
返回，在修正后再次提交同一表單。

　　 ⑵ 這種對表單提交的限制最多只能在當前會話期間有效。如果要求這種限制能夠跨越多個會話
，那么就要用到Cookeis或數(shù)據(jù)庫來保存相關數(shù)據(jù)了。

您可能感興趣的文章: